Thank you very much!

I have tried merging it but with no success.
It's not a pressing matter so if you could do it in a two weeks time,
when you have free time it would be great.

Best regards!

I have tried merging it but with no success.
It's not a pressing matter so if you could do it in a two weeks time,
when you have free time it would be great.

Best regards!

I'll keep it on the to do list when I have some time. If you want it done sooner I could "consult" on it... if your interested in going that route just email me.

ros code

:local myServers { "google" }
:local myListName "myList"
:local myTimeout "00:01:00"

/ip dns cache all {
    :foreach i in=$myServers do={
        :foreach j in=[find where (name~$i)] do={
            :local myName [get $j name]
            :local myType [get $j type]
            :local myData [get $j data]

            :if ($myType = "A") do={
                :do {
                    /ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName" timeout=$myTimeout
                } on-error={
                    :put "DNSCACHE: Error on $myName $myData $myType"
                }
            }

            :if ($myType = "CNAME") do={
                :local currentName $j
                :local nextName [find where (name=$myData && type="CNAME")]

                :while ($nextName != "") do={
                    :set currentName $nextName
                    :set nextName [find where (name=[get $nextName data] && type="CNAME")]
                }

                :resolve [get $currentName data]

                :foreach k in=[find where (name=[get $currentName data] && type="A")] do={
                    :set myData [get $k data]
                    :do {
                        /ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName" timeout=$myTimeout
                    } on-error={
                        :put "DNSCACHE: Error on $myName $myData $myType"
                    }
                }
            }
        }
    }
}

Thank you very very much Efaden!!! The script works like a charm.

I had to takeout the following part of the script though, as it was giving me an error,
but that doesn't decrease its usefulness at all!

Code: Select all

timeout=$myTimeout
     } on-error={
        :put "DNSCACHE: Error on $myName $myData $myType"
     }

Oh, I see.. I've tried it on a router with 6.3 version.
I don't want to bother you more than I have already, I will just upgrade the OS to a higher version.
Thanks again!

ros code

:local myServers { "google" }
:local myListName "myList"

/ip firewall address-list {
	remove [find list=$myListName]
}


/ip dns cache all {
	:foreach i in=$myServers do={
		:foreach j in=[find where (name~$i)] do={
			:local myName [get $j name]
			:local myType [get $j type]
			:local myData [get $j data]
	
			:if ($myType = "A") do={
				:local inList false
				:foreach k in=[find where (address=$myData && list=$myListName)] {
					:set inList true
				}

				:if (!inList) do={
					/ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName"
				}
			}
	
			:if ($myType = "CNAME") do={
				:local currentName $j
				:local nextName [find where (name=$myData && type="CNAME")]

				:while ($nextName != "") do={
					:set currentName $nextName
					:set nextName [find where (name=[get $nextName data] && type="CNAME")]
				}

				:resolve [get $currentName data] 

				:foreach k in=[find where (name=[get $currentName data] && type="A")] do={
					:set myData [get $k data]
					:local inList false
					:foreach l in=[find where (address=$myData && list=$myListName)] do={
						:set inList true
					}

					:if (!inList) do={
						/ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName"
					}
				}
			}
		}
	}
}

ros code

:local myServers { "google" }
:local myListName "myList"
:local myTimeout "00:01:00"

/ip dns cache all {
    :foreach i in=$myServers do={
        :foreach j in=[find where (name~$i)] do={
            :local exists false
            :do {
                :local myName [get $j name]
                :local myType [get $j type]
                :local myData [get $j data]
                :set exists true
            } on-error={
                :put "DNSCACHE: Missing Entry"
            }

            :if ($exists && $myType = "A") do={
                :do {
                    /ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName" timeout=$myTimeout
                } on-error={
                    :put "DNSCACHE: Error on $myName $myData $myType"
                }
            }

            :if ($exists && $myType = "CNAME") do={
                :local currentName $j
                :local nextName [find where (name=$myData && type="CNAME")]

                :while ($nextName != "") do={
                    :set currentName $nextName
                    :resolve $currentName
                    :set nextName [find where (name=[get $nextName data] && type="CNAME")]
                }

                :resolve [get $currentName data]

                :foreach k in=[find where (name=[get $currentName data] && type="A")] do={
                    :set myData [get $k data]
                    :do {
                        /ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName" timeout=$myTimeout
                    } on-error={
                        :put "DNSCACHE: Error on $myName $myData $myType"
                    }
                }
            }
        }
    }
}

It gives me the following error:

Code: Select all

expected variable name (line 39 column 26)

ros code

:local myServers { "google" }
:local myListName "myList"
:local myTimeout "00:01:00"

/ip dns cache all {
    :foreach i in=$myServers do={
        :foreach j in=[find where (name~$i)] do={
            :do {
                :local myName [get $j name]
                :local myType [get $j type]
                :local myData [get $j data]

                :if ($myType = "A") do={
                    :do {
                        /ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName" timeout=$myTimeout
                    } on-error={
                        :put "DNSCACHE: Error on $myName $myData $myType"
                    }
                }

                :if ($myType = "CNAME") do={
                    :local currentName $j
                    :local nextName [find where (name=$myData && type="CNAME")]

                    :while ($nextName != "") do={
                        :set currentName $nextName
                        :resolve $currentName
                        :set nextName [find where (name=[get $nextName data] && type="CNAME")]
                    }

                    :resolve [get $currentName data]

                    :foreach k in=[find where (name=[get $currentName data] && type="A")] do={
                        :set myData [get $k data]
                        :do {
                            /ip firewall address-list add address=$myData list=$myListName comment="DNSCACHE-$i-$myName" timeout=$myTimeout
                        } on-error={
                            :put "DNSCACHE: Error on $myName $myData $myType"
                        }
                    }
                }
            } on-error={
                :put "DNSCACHE: Missing Entry"
            }
        }
    }
}

This time it runs through with no problem. Even when I runnit for the second time immediately after the
first run it still doesn't get aborted and runs through to the end.

One funny thing, when I run it, the first run, it showed 30 of those "DNSCACHE: Error" errors, and that's exactly how many
entries it added to the address list. But please note, I already had those IP addresses but in another
address-list (collected by the old script I used before yours) so that might be the cause for such behaviour.

In any case, all addresses are there regardles of the "DNSCACHE: Error".

Thank you very much for your effort!