Help Troubleshooting DualWAN configuration.rsc

RouterOS General
1

Hello,
I’m trying to implement a DualWAN configuration, copying a setup someone (username: OpenSpeedTest) kindly posted here:
https://www.snbforums.com/threads/asus-dual-wan-router-load-balancing-and-failover-router-problems-and-fix.72579/#post-701501

Here’s a visual of what I’m trying to achieve:

I tried importing OpenSpeedTest’s configuration. I’ll paste his configuration here:

# jul/20/2021 13:38:32 by RouterOS 6.48.3
# software id = BY5Y-GDY1
#
# model = RB750Gr3
# serial number = XXXXXXXXXXX
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip firewall connection tracking
set enabled=yes
/ip address
add address=192.168.100.1/24 interface=ether5 network=192.168.100.0
add address=192.168.0.3 interface=ether1 network=192.168.0.1
add address=192.168.20.3 interface=ether2 network=192.168.20.1
/ip dns
set servers=8.8.8.8,8.8.4.4
/ip firewall filter
add action=drop chain=output disabled=yes dst-address=8.8.8.8 protocol=icmp
add action=drop chain=output disabled=yes dst-address=8.8.4.4 protocol=icmp
/ip firewall mangle
add action=accept chain=prerouting dst-address=192.168.0.0/24
add action=accept chain=prerouting dst-address=192.168.20.0/24
add action=accept chain=prerouting dst-address=192.168.100.0/24
add action=mark-connection chain=prerouting in-interface=ether5 \
new-connection-mark=ISP1 passthrough=yes per-connection-classifier=\
both-addresses-and-ports:3/0
add action=mark-connection chain=prerouting in-interface=ether5 \
new-connection-mark=ISP2 passthrough=yes per-connection-classifier=\
both-addresses-and-ports:3/1
add action=mark-connection chain=prerouting in-interface=ether5 \
new-connection-mark=ISP3 passthrough=yes per-connection-classifier=\
both-addresses-and-ports:3/2
add action=mark-routing chain=prerouting connection-mark=ISP1 in-interface=\
ether5 new-routing-mark=ISP1 passthrough=no
add action=mark-routing chain=prerouting connection-mark=ISP2 in-interface=\
ether5 new-routing-mark=ISP2 passthrough=no
add action=mark-routing chain=prerouting connection-mark=ISP3 in-interface=\
ether5 new-routing-mark=ISP3 passthrough=no
add action=mark-connection chain=prerouting in-interface=ether1 \
new-connection-mark=ISP1 passthrough=yes
add action=mark-connection chain=prerouting in-interface=ether2 \
new-connection-mark=ISP2 passthrough=yes
add action=mark-connection chain=prerouting in-interface=ether1 \
new-connection-mark=ISP3 passthrough=yes
add action=mark-routing chain=output connection-mark=ISP1 new-routing-mark=\
ISP1 passthrough=no
add action=mark-routing chain=output connection-mark=ISP2 new-routing-mark=\
ISP2 passthrough=no
add action=mark-routing chain=output connection-mark=ISP3 new-routing-mark=\
ISP3 passthrough=no
/ip firewall nat
add action=dst-nat chain=dstnat dst-address=192.168.0.3 dst-port=8080 \
protocol=tcp to-addresses=192.168.100.3 to-ports=8080
add action=dst-nat chain=dstnat dst-address=192.168.20.3 dst-port=3389 \
protocol=tcp to-addresses=192.168.100.3 to-ports=3389
add action=masquerade chain=srcnat src-address=192.168.100.0/24
/ip route
add distance=1 gateway=192.168.0.1 routing-mark=ISP1
add distance=2 gateway=192.168.20.1 routing-mark=ISP1
add distance=1 gateway=192.168.20.1 routing-mark=ISP2
add distance=2 gateway=192.168.0.1 routing-mark=ISP2
add distance=1 gateway=192.168.0.1 routing-mark=ISP3
add distance=2 gateway=192.168.20.1 routing-mark=ISP3
add distance=1 gateway=8.8.8.8 target-scope=30
add distance=1 gateway=8.8.4.4 target-scope=30
add distance=1 dst-address=8.8.4.4/32 gateway=192.168.20.1
add distance=1 dst-address=8.8.8.8/32 gateway=192.168.0.1
/ip service
set telnet disabled=yes
set ftp disabled=yes
set ssh disabled=yes
set api disabled=yes
set api-ssl disabled=yes
/system clock
set time-zone-name=Asia/Kolkata
/system ntp client
set enabled=yes primary-ntp=192.46.215.60 secondary-ntp=162.159.200.123 \
server-dns-names=8.8.8.8
/tool bandwidth-server
set enabled=no
/tool netwatch
add down-script="ip route disable [find dst-address=0.0.0.0/0 gateway=192.168.\
20.1]\r\
\n/ip firewall connection remove [find connection-mark=\"ISP2\"]\r\
\n:log error \"ISP2 down\"" host=8.8.4.4 interval=3s timeout=300ms \
up-script="ip route enable [find dst-address=0.0.0.0/0 gateway=192.168.20.\
1]\r\
\n/ip firewall connection remove [find connection-mark=\"ISP2\"]\r\
\nlog error \"ISP2 up\"\r\
\n/tool fetch url=\"https://go.vishnu.pro/BSNL\" keep-result=no"
add down-script="ip route disable [find dst-address=0.0.0.0/0 gateway=192.168.\
0.1]\r\
\n/ip firewall connection remove [find connection-mark=\"ISP1\"]\r\
\n/ip firewall connection remove [find connection-mark=\"ISP3\"]\r\
\nlog error \"ISP1 down\"" host=8.8.8.8 interval=2s timeout=500ms \
up-script="ip route enable [find dst-address=0.0.0.0/0 gateway=192.168.0.1\
]\r\
\n/ip firewall connection remove [find connection-mark=\"ISP1\"]\r\
\n/ip firewall connection remove [find connection-mark=\"ISP3\"]\r\
\nlog error \"ISP1 up\"\r\
\n/tool fetch url=\"https://go.vishnu.pro/Asianet\" keep-result=no"

When I tried importing, I got an error:

> import configuration.rsc
expected end of command (line 57 column 36)

I then entered one line at a time to see the specific error in action. Here’s a screenshot of the error:

I see from the comment at the top of the configuration that OpenSpeedTest was using RouterOS 6.48.3, but I’m using the latest version RouterOS 7.13. Perhaps the configuration needs to be updated? I would very much appreciate any help. Thank you in advance.

2

Enter the first part up to the IP address, then press TAB.
It will show you which entries are possible from there on.

You may want to check this page for differences in config moving from ROS6 to ROS7.
https://help.mikrotik.com/docs/display/ROS/Moving+from+ROSv6+to+v7+with+examples

For setting up of load balancing, use this video as guideline:
https://www.youtube.com/watch?v=nlb7XAv57tw
(don’t enable subtitles since you will miss important parts shown on the screen. Been there, done that)

3

Good opportunity to stop trying to copy and start trying to learn!
Print off the config and then start adding from winbox one config line at a time.
You will quickly find out that you cannot enter certain settings unless others are already setup… let the learning begin!!

@holvoe, you have me in stitches this morning, the OP has no capacity to move a config and yet your suggesting PCC LOL, too funny.

4

For any future people who stumble upon this post, here’s the fix to the configuration going from 6 to 7:

Change line 8 from this:

/ip firewall connection tracking

…to this:

/ip firewall conntrack