Community discussions

MikroTik App
 
dse
just joined
Topic Author
Posts: 1
Joined: Fri Mar 10, 2017 9:33 pm

Yet another DHCP to DNS script

Fri Mar 10, 2017 10:51 pm

This script intended to run as a DHCP server lease script and it manages (registers or removes) static DNS entries in accordance to DHCP lease allocation/expiration.

The script registers only fully qualified domain names (FQDN). Host part of the registering FQDN is the value of the "host-name" property of the lease or the "comment" property if the "host-name" is empty. Domain part is the value of the "domain" property of the corresponding DHCP server network. The script doesn't register DNS entries for invalid FQDNs with empty or undefined host or domain parts. Also the script doesn't register DNS entry when the entry with the same IP address or the FQDN already exists in the router's static DNS database.

Static DNS entries, managed by the script, have the tag #DHCP as a comment to distinguish them from the manually created ones.

The TTL of registering DNS entry is equal to the TTL of the corresponding DHCP lease.

On the DHCP lease expiration the script removes corresponding DNS entry with the same IP address, tagged as #DHCP in the comment.

The script logs various errors and informational messages with the tag DHCP2DNS. The logged messages are self-explanatory.

The script should be created as the standard system script. For the script to run for the given DHCP server, it's name should be assigned to the "lease-script" property of this server.

Source code follows.
:local DHCPtag
:set DHCPtag "#DHCP"

:if ( [ :len $leaseActIP ] <= 0 ) do={ :error "empty lease address" }

:if ( $leaseBound = 1 ) do=\
{
  :local ttl
  :local domain
  :local hostname
  :local fqdn
  :local leaseId
  :local comment

  /ip dhcp-server
  :set ttl [ get [ find name=$leaseServerName ] lease-time ]
  network 
  :set domain [ get [ find $leaseActIP in address ] domain ]
  
  .. lease
  :set leaseId [ find address=$leaseActIP ]

# Check for multiple active leases for the same IP address. It's weird and it shouldn't be, but just in case.

  :if ( [ :len $leaseId ] != 1) do=\
  {
   :log info "DHCP2DNS: not registering domain name for address $leaseActIP because of multiple active leases for $leaseActIP"
   :error "multiple active leases for $leaseActIP"
  }  

  :set hostname [ get $leaseId host-name ]
  :set comment [ get $leaseId comment ]
  /

  :if ( [ :len $hostname ] <= 0 ) do={ :set hostname $comment }

  :if ( [ :len $hostname ] <= 0 ) do=\
  {
    :log error "DHCP2DNS: not registering domain name for address $leaseActIP because of empty lease host-name or comment"
    :error "empty lease host-name or comment"
  }
  :if ( [ :len $domain ] <= 0 ) do=\
  {
    :log error "DHCP2DNS: not registering domain name for address $leaseActIP because of empty network domain name"
    :error "empty network domain name"
  }

  :set fqdn "$hostname.$domain"
  
  /ip dns static
  :if ( [ :len [ find name=$fqdn and address=$leaseActIP and disabled=no ] ] = 0 ) do=\
  {
    :log info "DHCP2DNS: registering static domain name $fqdn for address $leaseActIP with ttl $ttl"
    add address=$leaseActIP name=$fqdn ttl=$ttl comment=$DHCPtag disabled=no
  } else=\
  {
    :log error "DHCP2DNS: not registering domain name $fqdn for address $leaseActIP because of existing active static DNS entry with this name or address" 
  }
  /
} \
else=\
{
  /ip dns static
  :local dnsDhcpId 
  :set dnsDhcpId [ find address=$leaseActIP and comment=$DHCPtag ]

  :if ( [ :len $dnsDhcpId ] > 0 ) do=\
  {
    :log info "DHCP2DNS: removing static domain name(s) for address $leaseActIP"
    remove $dnsDhcpId
  }
  /
}
 
phin
just joined
Posts: 15
Joined: Mon Dec 04, 2017 11:25 pm

Re: Yet another DHCP to DNS script

Sun Feb 11, 2018 6:25 am

This is exactly what I was looking for. Thanks. Works as expected.
 
User avatar
emk2203
just joined
Posts: 10
Joined: Tue Feb 07, 2017 11:33 pm
Location: Germany

Re: Yet another DHCP to DNS script

Wed Aug 15, 2018 3:06 pm

Much better script than all the predecessors. This should be in the wiki.
RB 750G r3 + RB wAP G-5HacT2HnD
 
xrlls
just joined
Posts: 3
Joined: Sun Jan 13, 2019 4:43 pm

Re: Yet another DHCP to DNS script

Sun Jan 13, 2019 8:04 pm

Excellent! Just what I needed!
 
dca1
just joined
Posts: 2
Joined: Sat Aug 31, 2019 2:43 pm

Re: Yet another DHCP to DNS script

Sat Aug 31, 2019 3:01 pm

Can someone point me at what I'm doing wrong here? I've placed this script in the 'Lease Script' section of the DCHP Server setup window. I am watching my leases renew but I am now seeing anything being added to static DNS entries. I also tried adding it as a script and adding /system script run dhcptodns as the Lease Script. I just don't kinow how this is set up..
 
dca1
just joined
Posts: 2
Joined: Sat Aug 31, 2019 2:43 pm

Re: Yet another DHCP to DNS script

Sun Sep 01, 2019 1:46 pm

Answered my own question in the end. Script was erroring as I did not have local domain set. Set that and all good. Thanks a lot.
 
revamp
just joined
Posts: 2
Joined: Tue Dec 03, 2019 2:08 pm

Re: Yet another DHCP to DNS script

Tue Dec 03, 2019 2:20 pm

Need help. I just moved to MikroTik and this post is exactly what I needed.
After adding the script I can see in the logs the FQDN names are set correctly in the log.

However from the clients, the ping fails with FQDN (ping on just hostname works fine)

Here is my setup - ether4 (10.9.7.0/24) has the script assigned and domain "rev.local"
I have 2 windows machines with static leases
M1 - 10.9.7.11
M2 - 10.9.7.12

Machine are getting correct IP's, however their DNS server is 9.9.9.9 (which is set on the wan interface)

When I ping from M1
--> ping M2.rev.local --> cannot resolve....
--> ping M2 --> gets 10.9.7.2 and works fine
Same from M2

However, from the winBox terminal both M1 and M2 work fine with M1.rev.local and M2.rev.local

One more observation. there is M3 which does not have static lease (gets address 10.9.8.131) - can ping to M1, M2 but not M1.rev.local

Am I missing anything...
 
mniewiera
just joined
Posts: 7
Joined: Wed Dec 27, 2017 4:52 pm

Re: Yet another DHCP to DNS script

Tue Dec 03, 2019 7:31 pm

From what i understand your problem is that the machines (m1, m2 and m3) use 9.9.9.9 as DNS Servers.
They should use the mikrotik as DNS Server. This way they can resolve m1.rev.local and DNS requests for public domains (for example google.com) is forwarded to 9.9.9.9.

I guess that you can even ping m1 or m2 but not .rev.local is coming from the WINS Service. (In this case i guess you are using windows as operating system?)

You can change what DNS Server they are getting in the DHCP section.
 
revamp
just joined
Posts: 2
Joined: Tue Dec 03, 2019 2:08 pm

Re: Yet another DHCP to DNS script

Tue Dec 03, 2019 7:47 pm

Thanks for the reply.

The Windows machines are set to get DNS settings dynamically from DHCP settings
WINS yes, but in my earlier DD-WRT, same worked perfectly fine.

I need to study how to setup the internal DNS (any pointers).
 
mniewiera
just joined
Posts: 7
Joined: Wed Dec 27, 2017 4:52 pm

Re: Yet another DHCP to DNS script

Tue Dec 03, 2019 10:04 pm

I think your DNS is working fine because it worked from winbox.
So the DNS Server set on your client machines is set to 9.9.9.9?
If so, then it just can't work. Because 9.9.9.9 can't resolve your internal DNS entries. Only the mikrotik can.
If the DNS is set to 9.9.9.9, and this setting is coming from the DHCP Server, then you have to change what is assigned to them.
I guess your DHCP is also the mikrotik? If so then you have to change the configuration on the DHCP Server in the mikrotik. Since i'm currently not within reach of a mikrotik device i can't tell you where to go right now. But in the mikrotik wiki should be some helpful article.
So you (at least currently) don't have to study how DNS works. DHCP is where your problem is in my opinion.
 
Ameeno
just joined
Posts: 16
Joined: Sun Apr 29, 2018 1:25 am

Re: Yet another DHCP to DNS script

Mon Feb 03, 2020 8:33 am

hello, is this broken?

I receive the following error when script is run:

"empty lease address"

this seems to relate to the value of :if ( [ :len $leaseActIP ] <= 0 ) do={ :error "empty lease address" }


perhaps Mikrotik has changed/removed/renamed this variable?
 
User avatar
willianwrm
just joined
Posts: 11
Joined: Mon Jun 06, 2016 8:54 pm
Location: -21.2330138,-44.9962488
Contact:

Re: Yet another DHCP to DNS script

Wed Apr 15, 2020 7:41 pm

I receive the following error when script is run:

"empty lease address"

It's working fine in the long-term version 6.45.8.
You need to put this script in the Lease Script of the DHCP Server, it will be called automatically by new leases.

One thing I did notice is that the script does not run at renew address (after expiration time) but only when the host request a new lease.
 
sebaz
just joined
Posts: 1
Joined: Mon Mar 23, 2020 11:37 am

Re: Yet another DHCP to DNS script

Sun Apr 26, 2020 3:48 pm

I'm posting this since it might help someone. On my RouterOS v6.46.5 I was having problems with script also where in the log I could see messages like
DHCP2DNS: not registering domain name for address xxx.yyy.www.zzz because of empty lease host-name or comment
for some of the devices.

It turns out hostname was not read with following call
:set hostname [ get $leaseId host-name ]
so my solution was to add
:if ( [ :len $hostname ] <= 0 ) do={ :set hostname $"lease-hostname" }
line so you have following in script:
:if ( [ :len $hostname ] <= 0 ) do={ :set hostname $comment }

:if ( [ :len $hostname ] <= 0 ) do={ :set hostname $"lease-hostname" }
 
RackKing
Member
Member
Posts: 381
Joined: Wed Oct 09, 2013 1:59 pm

Re: Yet another DHCP to DNS script

Thu Jul 02, 2020 7:32 pm

Anyone have an updated version of this? It is not working for me on 6.47. Thanks.
 
jbl42
just joined
Posts: 7
Joined: Sun Jun 21, 2020 12:58 pm

Re: Yet another DHCP to DNS script

Sun Jul 05, 2020 10:50 pm

Thanks for the script. This should be in the official docs.

I created a slightly modified version:
  • Strip spaces and \00 chars from DHCP lease host names before combining them with the domain to build DNS fqdn. Some DHCP clients, in my case smart Zyxel switches, register with host names with spaces and trailing \00 chars (this is most likely a Zyxel FW bug)
  • Generate a hostname for DHCP clients registering with empty host names to create a static DNS A record for all DHCP clients. Most Android devices since Version 8 do not provide host names with DHCP reqs. I like to have working DNS for all clients
  • Make log prefix configurable
:local DHCPtag   "#*# Created by DHCP2DNS #*#"
:local LogPrefix "DHCP2DNS ($leaseServerName)"

###
# Functions

# remove \0 and spaces from string passed as inStr=<string>
:local trimString do=\
{
  :local outStr
  :for i from=0 to=([:len $inStr] - 1) do=\
  {
    :local tmp [:pick $inStr $i];
    :if (($tmp !=" ") and ($tmp !="\00")) do=\
    {
      :set outStr ($outStr . $tmp)
    }
  }
  :return $outStr
}

# "a.b.c.d" -> "a-b-c-d" for IP addresses used as replacement for missing host names
:local ip2Host do=\
{
  :local outStr
  :for i from=0 to=([:len $inStr] - 1) do=\
  {
    :local tmp [:pick $inStr $i];
    :if ($tmp =".") do=\
    {
      :set tmp "-"
    }
    :set outStr ($outStr . $tmp)
  }
  :return $outStr
}

###
# Script entry point
#
# Expected environment variables:
# leaseBound         1 = lease bound, 0 = lease removed
# leaseServerName    Name of DHCP server
# leaseActIP         IP address of DHCP client

:if ( [ :len $leaseActIP ] <= 0 ) do=\
{
  :log error "$LogPrefix: empty lease address"
  :error "empty lease address"
}

:if ( $leaseBound = 1 ) do=\
{
  # new DHCP lease added
  
  /ip dhcp-server
  :local ttl [ get [ find name=$leaseServerName ] lease-time ]
  network 
  :local domain [ get [ find $leaseActIP in address ] domain ]
  :set domain [ $trimString inStr=$domain ]

  .. lease
  :local leaseId [ find address=$leaseActIP ]

  # Check for multiple active leases for the same IP address. It's weird and it shouldn't be, but just in case.
  :if ( [ :len $leaseId ] != 1) do=\
  {
    :log warning "$LogPrefix: Multiple active DHCP leases for '$leaseActIP' (???)"
    :error "Multiple active DHCP leases for '$leaseActIP' (???)"
  }  
  :local hostname [ get $leaseId host-name ]
  :set hostname [ $trimString inStr=$hostname ]

  :if ( [ :len $hostname ] <= 0 ) do=\
  {
    :set hostname [ $ip2Host inStr=$leaseActIP ]
    :log info "$LogPrefix: Empty hostname for '$leaseActIP', using generated host name '$hostname'"
  }
  :if ( [ :len $domain ] <= 0 ) do=\
  {
    :log warning "$LogPrefix: Empty domainname for '$leaseActIP', cannot create static DNS name"
    :error "Empty domainname for '$leaseActIP'"
  }

  :local fqdn ($hostname . "." .  $domain)

  /ip dns static
  :if ( [ :len [ find name=$fqdn and address=$leaseActIP and disabled=no ] ] = 0 ) do=\
  {
    add address=$leaseActIP name=$fqdn ttl=$ttl comment=$DHCPtag disabled=no
    :log info "$LogPrefix: Static domain name '$fqdn' created for '$leaseActIP' with ttl '$ttl'"
  }\
  else=\
  {
    :log warning "$LogPrefix: '$fqdn' already exists, cannot create static DNS name for '$leaseActIP'"
    :error "$LogPrefix: '$fqdn' already exists"
  }
}\
else=\
{
  # DHCP lease removed

  /ip dns static
  :local dnsDhcpId
  :set dnsDhcpId [ find address=$leaseActIP and comment=$DHCPtag ]
  :if ( [ :len $dnsDhcpId ] > 0 ) do=\
  {
    remove $dnsDhcpId
    :log info "$LogPrefix: Static DNS name(s) for '$leaseActIP' removed"
  }
}

For more flexibility, the above script can be stored in a /system script. This allows to use the same script from all DHCP servers to ease maintenance by putting a small wrapper script into the DHCP server lease script property:

:local scriptName "dhcp2dns.rsc"
:do {
  :local scriptSrc [ /system script get [ find name=$scriptName  ] source ]
  :local scriptObj [ :parse $scriptSrc ]
  $scriptObj leaseBound=$leaseBound  leaseServerName=$leaseServerName leaseActIP=$leaseActIP
} on-error={ :log warning "DHCP server '$leaseServerName' lease script error" };
Tested on RB4011 V6.47.1
Last edited by jbl42 on Sun Aug 09, 2020 4:44 pm, edited 1 time in total.
 
User avatar
HiltonT
Frequent Visitor
Frequent Visitor
Posts: 76
Joined: Mon Feb 07, 2011 4:24 am
Location: 'Srayamate
Contact:

Re: Yet another DHCP to DNS script

Sat Jul 11, 2020 10:25 am

Anyone have an updated version of this? It is not working for me on 6.47. Thanks.
I concur.
Regards,
Hilton Travis
 
User avatar
Smoerrebroed
just joined
Posts: 17
Joined: Mon Feb 12, 2018 10:21 am

Re: Yet another DHCP to DNS script

Mon Sep 07, 2020 11:16 am

Good script! The only issue I had with it is that it will automatically assume the same lease-time for all (even static) leases, which might not be the case, so I changed
/ip dhcp-server
:set ttl [ get [ find name=$leaseServerName ] lease-time ]
network
to
/ip dhcp-server lease
:set ttl [ get [ find address=$leaseActIP ] lease-time ]
/ip dhcp-server network
Other than that, many thanks for contributing this!
 
User avatar
Smoerrebroed
just joined
Posts: 17
Joined: Mon Feb 12, 2018 10:21 am

Re: Yet another DHCP to DNS script

Thu Sep 10, 2020 1:57 pm

Okay, so I noticed that with my change, only leases that have their own lease-time set will be created in the DNS cache, so please use this instead:
    /ip dhcp-server lease
    :set ttl [ get [ find address=$leaseActIP ] lease-time ]
    :if ( [ :len $ttl ] <= 0 ) do={
        /ip dhcp-server
        :set ttl [ get [ find name=$leaseServerName ] lease-time ]
    }
 
nescafe2002
Long time Member
Long time Member
Posts: 692
Joined: Tue Aug 11, 2015 12:46 pm
Location: Netherlands

Re: Yet another DHCP to DNS script

Thu Sep 10, 2020 3:06 pm

Actually setting dns ttl equal to lease time doesn't make any sense and only leads to unexpected behavior especially for longer lease times..
 
neutronlaser
Member
Member
Posts: 389
Joined: Thu Jan 18, 2018 5:18 pm

Re: Yet another DHCP to DNS script

Sat Sep 12, 2020 9:56 pm

Someone post the latest and best script on wiki.

Who is online

Users browsing this forum: No registered users and 25 guests