Community discussions

MikroTik App
 
raminmalek
Member Candidate
Member Candidate
Topic Author
Posts: 156
Joined: Sun Nov 02, 2008 5:51 pm

Scrpit Working On version 6 For Get backup And Transfer to remote FTP server

Sun Sep 18, 2022 8:40 am

Hi Dear Friends I need Script that shedulet every week To get backup From my router And Transfer to the Remote FTP

Please share with me
 
User avatar
Jotne
Forum Guru
Forum Guru
Posts: 3279
Joined: Sat Dec 24, 2016 11:17 am
Location: Magrathean

Re: Scrpit Working On version 6 For Get backup And Transfer to remote FTP server  [SOLVED]

Sun Sep 18, 2022 8:54 am

# Backup sctip to send rsc and binary backup to FTP server
#
# Remember to create a folder with name as show $info_$serial
#
# Jotne 2022
# ver 1.2 added path
# ver 1.3 fixed missing serial


:local Server "192.168.88.5"
:local User "FTPUser"
:local Pass "FTPPassword"


/system
:local date [clock get date]
:set $date ([:pick "$date" 0 3].".".[:pick "$date" 4 6].".".[:pick "$date" 7 11])
:local time [clock get time]
:set $time ([:pick "$time" 0 2].".".[:pick "$time" 3 5])
:local info [identity get name]

:local board ([resource get board-name])
:local serial
:if ($board!="CHR") do={
	:set $serial [routerboard get serial-number]
} else={
	:set $serial "CHR"
}
:local Version [resource get version]

# Take readable backup
:if ($Version~"^7") do={
	[:parse "/export show-sensitive file=backup.rsc"]
} else={
	/export file="backup.rsc"
}
:delay 2s

# Take binary backup
/system backup save name="backup"
:delay 2s


# Send files to FTP server

/tool fetch address="$Server" src-path="backup.rsc" user="$User" mode=ftp password="$Pass" dst-path="$info_$serial/$info_$serial_$date_$time.rsc" upload=yes port=21
:delay 2s
/tool fetch address="$Server" src-path="backup.backup" user="$User" mode=ftp password="$Pass" dst-path="$info_$serial/$info_$serial_$date_$time.backup" upload=yes port=21
:delay 2s

# Remove temp files
/file remove backup.backup
/file remove backup.rsc
:log info "Backup router=$info serial=$serial ok"
 
raminmalek
Member Candidate
Member Candidate
Topic Author
Posts: 156
Joined: Sun Nov 02, 2008 5:51 pm

Re: Scrpit Working On version 6 For Get backup And Transfer to remote FTP server

Sun Sep 18, 2022 10:21 am

Thanks I need Standard file Name For widnows Format used Filezilla server On windows Server
Colons are not valid in filenames on Windows

STOR content_742907D17019/content_742907D17019_sep.18.2022_11.46.rsc
550 Filename invalid
 
User avatar
Jotne
Forum Guru
Forum Guru
Posts: 3279
Joined: Sat Dec 24, 2016 11:17 am
Location: Magrathean

Re: Scrpit Working On version 6 For Get backup And Transfer to remote FTP server

Sun Sep 18, 2022 10:44 am

As written in the script. You need to make folder that it tries to write to.
For your files, it would be: content_742907D17019

I could have put all routers in one folder, but that would be messy if you have many routers.

PS some strange Identity name of a router: content

Who is online

Users browsing this forum: Bing [Bot], diamuxin, Google [Bot] and 20 guests