MikroTik

Posted: **Tue May 20, 2014 1:02 am**

ros code

# Usage: [$returnOctet <ip> <octet number (0-3)>]
# Input an IP Address and 0-3 argument to return a specific octet number 
:global returnOctet do={
    :if ($1="") do={ :error "You did not specify an IP Address."; }
    :if ($2="") do={ :error "You did not specify an octet to return."; }
    :if (($2>3) || ($2<0)) do={ :error "Octet argument out of range."; }
    :local decimalPos "0";
    :local octet1;
    :local octet2;
    :local octet3;
    :local octet4;
    :set decimalPos [:find $1 "."];
    :set octet1 [:pick $1 0 $decimalPos];
    :set decimalPos ($decimalPos+1);
    :set octet2  [:pick $1 $decimalPos [:find $1 "." $decimalPos]];
    :set decimalPos ([:find $1 "." $decimalPos]+1);
    :set octet3  [:pick $1 $decimalPos [:find $1 "." $decimalPos]];
    :set decimalPos ([:find $1 "." $decimalPos]+1);
    :set octet4 [:pick $1 $decimalPos [:len $1]];
    :if (($octet1<0 || $octet1>255) || ($octet2<0 || $octet2>255) || ($octet3<0 || $octet3>255) || ($octet4<0 || $octet4>255)) do={ :error "Octet out of range."; }
    :if ($2=0) do={ :return $octet1; }
    :if ($2=1) do={ :return $octet2; }
    :if ($2=2) do={ :return $octet3; }
    :if ($2=3) do={ :return $octet4; }
}

I'm on RouterOS 6.7. When I created this code everything works fine but since I converted it to a function, I'm having trouble figuring out why when I insert a :put directly after I set octet4 it shows the correct value but then the return value somehow gives me the value for $octet3. Arguments 0-2 all produce the expected results.

Posted: **Tue May 20, 2014 2:51 am**

:global returnOctet do={
 :if ([:typeof [:toip $1]] != "ip") do={ :error message="You did not specify any VALID IP Address."; };
 :if ( (($2 + 0) < 1) || (($2 + 0) > 4) ) do={ :error message="You did not specify any VALID octet to return."; };
 :local workString value=[:tostr [:toip $1]];
 :local endString value="";
 :local thisChar value="";
 :for i from=0 to=[:len $workString] step=1 do={
  :set $thisChar value=[:pick $workString $i ($i+1)];
  :if ($thisChar = ".") do={ :set $thisChar value=",";};
  :set $endString value=($endString.$thisChar);
 };
 :local resultArray value=[:toarray $endString];
 :return value=($resultArray->($2 - 1));
}

EDIT: removed :put "yyy" debug string

Posted: **Tue May 20, 2014 4:53 pm**

I appreciate the response rextended and the time you took to rewrite the function but I'd still like to know why the code that I wrote is not returning the proper results. I've upgraded to Router OS 6.13 and the issue still persists.

Posted: **Tue May 20, 2014 5:11 pm**

Following should fix your problem

ros code

:if ($2="0") do={ :return $octet1; }
    :if ($2="1") do={ :return $octet2; }
    :if ($2="2") do={ :return $octet3; }
    :if ($2="3") do={ :return $octet4; }

Sometimes it is not possible to guess correct type, so unexpected results may appear.
Function variable is a string and you are comparing it to integer.

Posted: **Tue May 20, 2014 5:25 pm**

I should have known it was something as easy at that. Thank you so much.

Posted: **Tue May 20, 2014 6:04 pm**

In colors I evidence all necessary type check / convert

:global returnOctet do={
:if ([:typeof [:toip $1]] != "ip") do={ :error message="You did not specify any VALID IP Address."; };
:if ( (($2 + 0) < 1) || (($2 + 0) > 4) ) do={ :error message="You did not specify any VALID octet to return."; };
:local workString value=[:tostr [:toip $1]];
:local endString value="";
:local thisChar value="";
:for i from=0 to=[:len $workString] step=1 do={
:set $thisChar value=[:pick $workString $i ($i+1)];
:if ($thisChar = ".") do={ :set $thisChar value=",";};
:set $endString value=($endString.$thisChar);
};
:local resultArray value=[:toarray $endString];
:return value=($resultArray->($2 - 1));
}

($2 + 0) and ($2 - 1) convert the $2 value surely to integer, because one addition are made...

Posted: **Fri Jun 13, 2014 10:27 pm**

Here was my final working version of my returnOctet function. I added the ability to return all octets as an array.

ros code

# Usage: [$returnOctet <ip> <octet number (0-4)>]
# Input an IP Address and 0-3 argument to return a specific octet number or 4 to return the entire array
:global returnOctet do={
    :if ($1="") do={ :error "You did not specify an IP Address."; }
    :if ($2="") do={ :error "You did not specify an octet to return."; }
    :if (($2>"4") || ($2<"0")) do={ :error "Octet argument out of range."; }
    :local decimalPos "0";
    :local octet1;
    :local octet2;
    :local octet3;
    :local octet4;
    :local octetArray; 
    :set decimalPos [:find $1 "."];
    :set octet1 [:pick $1 0 $decimalPos];
    :set decimalPos ($decimalPos+1);
    :set octet2  [:pick $1 $decimalPos [:find $1 "." $decimalPos]];
    :set decimalPos ([:find $1 "." $decimalPos]+1);
    :set octet3  [:pick $1 $decimalPos [:find $1 "." $decimalPos]];
    :set decimalPos ([:find $1 "." $decimalPos]+1);
    :set octet4 [:pick $1 $decimalPos [:len $1]];
    :set octetArray [:toarray "$octet1,$octet2,$octet3,$octet4"];
    :if (($octet1<"0" || $octet1>"255") || ($octet2<"0" || $octet2>"255") || ($octet3<"0" || $octet3>"255") || ($octet4<"0" || $octet4>"255")) do={ :error "Octet out of range."; }
    :if ($2="0") do={ :return $octet1; }
    :if ($2="1") do={ :return $octet2; }
    :if ($2="2") do={ :return $octet3; }
    :if ($2="3") do={ :return $octet4; }
    :if ($2="4") do={ :return $octetArray; }
}

Posted: **Fri Jun 13, 2014 11:53 pm**

Good, I add the same ability to my version

:global returnOctet do={
:if ([:typeof [:toip $1]] != "ip") do={ :error message="You did not specify any VALID IP Address."; };
:if ( (($2 + 0) < 1) || (($2 + 0) > 5) ) do={ :error message="You did not specify any VALID argument to return."; };
:local workString value=[:tostr [:toip $1]];
:local endString value="";
:local thisChar value="";
:for i from=0 to=[:len $workString] step=1 do={
:set $thisChar value=[:pick $workString $i ($i+1)];
:if ($thisChar = ".") do={ :set $thisChar value=",";};
:set $endString value=($endString.$thisChar);
};
:local resultArray value=[:toarray $endString];
:if (($2 + 0) = 4) do={ :return value=$resultArray; } else={ :return value=($resultArray->($2 - 1)); };
}

:global returnOctet do={
 :if ([:typeof [:toip $1]] != "ip") do={ :error message="You did not specify any VALID IP Address."; };
 :if ( (($2 + 0) < 1) || (($2 + 0) > 5) ) do={ :error message="You did not specify any VALID argument to return."; };
 :local workString value=[:tostr [:toip $1]];
 :local endString value="";
 :local thisChar value="";
 :for i from=0 to=[:len $workString] step=1 do={
  :set $thisChar value=[:pick $workString $i ($i+1)];
  :if ($thisChar = ".") do={ :set $thisChar value=",";};
  :set $endString value=($endString.$thisChar);
 };
 :local resultArray value=[:toarray $endString];
 :if (($2 + 0) = 4) do={ :return value=$resultArray; } else={ :return value=($resultArray->($2 - 1)); };
}

Posted: **Wed Sep 17, 2014 6:45 am**

How do you use this script?

Posted: **Fri Jul 17, 2015 11:42 pm**

How do you use this script?

Obviously the response is a year late or so but, to answer your question, all you do is copy and paste the ROS code above into whatever script your working on and as indicated in the usage statement above, you can call on it like this from inside your script:

:local ipAddress "10.1.1.20";
:put [$returnOctet $ipAddress 0];

It would return the first octet of "10" and print it to the terminal window. Also as noted above, the second argument 0-3 returns what octet you're looking for. So in the case above, if you put the number 0 through 3, it would return "10", "1", "1", or "20" respectively. It is very helpful in situations where you need to manipulate a specific octet of a variable that contains an IP address.

Or you can directly input the variable and it would output the same thing like this:

:put [$returnOctet 10.1.1.20 0]

Once you've ran the script one time, since it's a global variable, you could then call it directly from the terminal the same way or use it in any other script for that matter as long as you declare ":global returnOctet;" to initialize the variable before you use it as long as you haven't unset the variable by calling ":set returnOctet;" or rebooted your router since you ran the script. Global variables aren't kept after a reboot.

To actually run a script there are several ways that I know of (probably more than this), by opening a terminal and typing "/system script run nameOfScript" or in Winbox go to System > Scripts > Select the script and hit Run Script but you won't see any output that way.

Posted: **Sun Jun 14, 2020 3:10 am**

Short version:

 {
local CurIP "192.168.10.0/24"
put ("IP1oct: ".[pick $CurIP  0 [find $CurIP "."]])
put ("IP2oct: ".[pick $CurIP  0 [find $CurIP "." ([find $CurIP "."]+1)  ]])
put ("IP3oct: ".[pick $CurIP  0 [find $CurIP "." ([find $CurIP "." ([find $CurIP "."]+1)]+1)  ]])
put ("IP4oct: ".[pick $CurIP  0 [find $CurIP "/" ]])                                             
}                                                   
IP1oct: 192
IP2oct: 192.168
IP3oct: 192.168.10
IP4oct: 192.168.10.0

Edit after answer @eworm

{
local CurIP "192.168.10.1/24"
local IP4oct [pick $CurIP  0 [find $CurIP "/" ]]
put ("IP1oct: ".($IP4oct & 255.0.0.0))
put ("IP2oct: ".($IP4oct & 255.255.0.0))
put ("IP3oct: ".($IP4oct & 255.255.255.0))
put ("IP4oct: ".$IP4oct)
}
IP1oct: 192.0.0.0
IP2oct: 192.168.0.0
IP3oct: 192.168.10.0
IP4oct: 192.168.10.1

Posted: **Mon Jun 15, 2020 5:00 pm**

RouterOS supports bitwise operations, so you can calculate IP addresses like this, for example get the first octet:

:put (192.168.10.0 & 255.0.0.0)
192.0.0.0

Possibly useful to shorten your functions even further.

MikroTik

Return IP Octet Function

Return IP Octet Function

ros code

Re: Function returning wrong value

Re: Function returning wrong value

Re: Function returning wrong value

ros code

Re: Function returning wrong value

Re: Function returning wrong value

Re: Function returning wrong value

ros code

Re: Return IP Octet Function

Re: Return IP Octet Function

Re: Return IP Octet Function

Re: Return IP Octet Function

Re: Return IP Octet Function