[SOLVED] Using Dynamic Variable Names

Tal · Sat Aug 15, 2015 5:45 am

Is there any way to use dynamic names for variables?

Ex:

:global VALUE true

:foreach varname in "VAR1\n\rVAR2\n\rVAR3" \
do={
	:global "$varname" $VALUE
}

I would think that the above code should work, but it doesn't, because :global doesn't like taking a variable name from a variable. Any way to get around this?

favincen · Thu Aug 27, 2015 3:59 pm

This code doesn't work. But it may give a hint toward a solution :

 :foreach varname in={"VAR1" ; "VAR2" ; "VAR3"  } do={:parse ":global $varname \$VALUE" }

Hope it can help.

favincen · Thu Aug 27, 2015 4:53 pm

Using ":execute" instead of ":parse", it works

:

:foreach varname in={"VAR1" ; "VAR2" ; "VAR3"  } do={:execute ":global $varname \$VALUE" }

Tal · Fri Aug 28, 2015 6:55 am

Using ":execute" instead of ":parse", it works :
Code: Select all
:foreach varname in={"VAR1" ; "VAR2" ; "VAR3"  } do={:execute ":global $varname \$VALUE" }

I used $VALUE instead of \$VALUE, but it worked perfectly.

Thanks guys.

favincen · Fri Aug 28, 2015 11:26 am

I used $VALUE instead of \$VALUE, but it worked perfectly.

Hi Tal,

Without "\" it works for most values. But If VALUE contains, for example, a string with spaces or special characters, "$VALUE" won't work while "\$VALUE" will...

BTW, a warning: I may have missed something but AFAIK, if the ":execute" f command fails, you get no error message of any kind.

Fabrice

Tal · Fri Aug 28, 2015 7:01 pm

I used $VALUE instead of \$VALUE, but it worked perfectly.
Hi Tal,

Without "\" it works for most values. But If VALUE contains, for example, a string with spaces or special characters, "$VALUE" won't work while "\$VALUE" will...

BTW, a warning: I may have missed something but AFAIK, if the ":execute" f command fails, you get no error message of any kind.

Fabrice

It didn't seem to work for me when I used "\$VALUE", but I'll try again. Pretty useful bit of info - thanks.

Winand · Sat Aug 04, 2018 1:13 pm

This code doesn't work. But it may give a hint toward a solution :

You just need square brackets:

foreach varname in={"VAR1"; "VAR2"; "VAR3"} do={[parse "global $varname true"]}

randomwalk · Sat Apr 13, 2019 11:28 pm

randomwalk · Wed Dec 16, 2020 9:44 am

Works with global, but not possible with local. Is the any solution for local variables?

Store the dynamically created local variables in an array.


{
    :local qty 9;           # number of variables to create
    :local varname "myvar"; # name for the variables

    :local myarray [:toarray ""];            # create empty array
    :for i from=1 to=$qty do={
        :local tmp ($varname . [:tostr $i]); # dynamically construct name of the variable
        :set ($myarray->$tmp) "";            # push the newly created variable into the array
    }
# setting the variables
    :set ($myarray->"myvar1") "plaintext"
    :set ($myarray->"myvar2") {"abc"}
    :set ($myarray->"myvar3") 
    :set ($myarray->"myvar4") true
    :set ($myarray->"myvar5") 127.0.0.1
    :set ($myarray->"myvar6") 23:59:59
    :set ($myarray->"myvar7") 192.168.88.0/24
    :set ($myarray->"myvar8") ::ffff:192.0.2.128
    :set ($myarray->"myvar9") 2001:0DB8:0000:000b::/64

# reading the variables
    :put ( "myvar1=" . ($myarray->"myvar1") . "   type=" . [ :typeof ($myarray->"myvar1") ] )
    :put ( "myvar2=" . ($myarray->"myvar2") . "   type=" . [ :typeof ($myarray->"myvar2") ] )
    :put ( "myvar3=" . ($myarray->"myvar3") . "   type=" . [ :typeof ($myarray->"myvar3") ] )
    :put ( "myvar4=" . ($myarray->"myvar4") . "   type=" . [ :typeof ($myarray->"myvar4") ] )
    :put ( "myvar5=" . ($myarray->"myvar5") . "   type=" . [ :typeof ($myarray->"myvar5") ] )
    :put ( "myvar6=" . ($myarray->"myvar6") . "   type=" . [ :typeof ($myarray->"myvar6") ] )
    :put ( "myvar7=" . ($myarray->"myvar7") . "   type=" . [ :typeof ($myarray->"myvar7") ] )
    :put ( "myvar8=" . ($myarray->"myvar8") . "   type=" . [ :typeof ($myarray->"myvar8") ] )
    :put ( "myvar9=" . ($myarray->"myvar9") . "   type=" . [ :typeof ($myarray->"myvar9") ] )
}

output:
[admin@rb] >
myvar1=plaintext type=str
myvar2=abc type=array
myvar3= type=nothing
myvar4=true type=bool
myvar5=127.0.0.1 type=ip
myvar6=23:59:59 type=time
myvar7=192.168.88.0/24 type=ip-prefix
myvar8=::ffff:192.0.2.128 type=ip6
myvar9=2001:db8:0:b::/64 type=ip6-prefix

[SOLVED] Using Dynamic Variable Names

[SOLVED] Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Re: Using Dynamic Variable Names

Who is online