Community discussions

MikroTik App
 
HomeisNothing
just joined
Topic Author
Posts: 1
Joined: Mon Jan 23, 2023 4:25 am

Help with VLANs on Bridge

Mon Jan 23, 2023 4:34 am

Hi Guys,

I just bought a Mikrotik CRS309-1G-8 for the purpose of using it as my out-of-band iSCSI storage VLAN. The plan is for the 1G interface to be my management interface (connecting to my other switch) and the rest as iSCSI VLAN (172,173) to enable iSCSI multipathing. I can get my management interface up and reachable but not my other 2 VLANs. My systems on the SFP ports cannot ping each other or the gateway (gateway is added for testing. I don't need any address to be routeable)

Appreciate any help with my configuration.. I am struggling as this is very different from configuring other switches such as Aruba/Cisco. BTW, I am not switching to SwitchOS as I understand the configuration is Web (no HTTPS/SSH).

Here is my configuration
/interface bridge
add admin-mac=<redacted> auto-mac=no name=MgmtBridge
add name=iSCSI-Bridge
/interface vlan
add interface=MgmtBridge name=Mgmt111 vlan-id=111
add interface=iSCSI-Bridge name=iSCSIBridge_172 vlan-id=172
add interface=iSCSI-Bridge name=iSCSIBridge_173 vlan-id=173
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip hotspot profile
set [ find default=yes ] html-directory=hotspot
/port
set 0 name=serial0
/interface bridge port
add bridge=MgmtBridge interface=ether1 pvid=995
add bridge=iSCSI-Bridge interface=sfp-sfpplus1
add bridge=iSCSI-Bridge interface=sfp-sfpplus2
add bridge=iSCSI-Bridge interface=sfp-sfpplus3
add bridge=iSCSI-Bridge interface=sfp-sfpplus4
/interface bridge vlan
add bridge=MgmtBridge tagged=MgmtBridge vlan-ids=111
add bridge=iSCSI-Bridge tagged=iSCSI-Bridge,sfp-sfpplus1,sfp-sfpplus2,sfp-sfpplus3,sfp-sfpplus4 vlan-ids=172,173
/ip address
add address=172.16.11.13/27 interface=MgmtBridge network=172.16.11.0
add address=192.168.172.1/28 interface=iSCSIBridge_172 network=192.168.172.0
add address=192.168.173.1/28 interface=iSCSIBridge_173 network=192.168.173.0
/ip route
add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=172.16.11.1 pref-src="" routing-table=main scope=10 suppress-hw-offload=no target-scope=10
/system ntp client servers
add address=172.16.12.12
/system routerboard settings
set boot-os=router-os
 
ConradPino
Member
Member
Posts: 337
Joined: Sat Jan 21, 2023 12:44 pm
Contact:

Re: Help with VLANs on Bridge

Tue Jan 24, 2023 4:58 pm

Adding another bridge is not recommended:
RouterOS / Bridging and Switching / Bridging and Switching Case Studies / Layer2 misconfiguration / Bridges on a single switch chip
https://help.mikrotik.com/docs/display/ ... switchchip
Expect follow post with recommendation
 
ConradPino
Member
Member
Posts: 337
Joined: Sat Jan 21, 2023 12:44 pm
Contact:

Re: Help with VLANs on Bridge

Tue Jan 24, 2023 5:29 pm

One bridge default PVID; VLAN off until configured.
/interface bridge
add admin-mac=<redacted> auto-mac=no name=bridge pvid=1
set numbers=bridge vlan-filtering=no
Add every port with untagged default (pvid):
/interface bridge port
add bridge=bridge interface=ether1 pvid=111
add bridge=bridge interface=sfp-sfpplus1 pvid=172
add bridge=bridge interface=sfp-sfpplus2 pvid=173
add bridge=bridge interface=sfp-sfpplus3 pvid=172
add bridge=bridge interface=sfp-sfpplus4 pvid=173
add bridge=bridge interface=sfp-sfpplus5 pvid=172
add bridge=bridge interface=sfp-sfpplus6 pvid=173
add bridge=bridge interface=sfp-sfpplus7 pvid=172
add bridge=bridge interface=sfp-sfpplus8 pvid=173
Assign VLAN port mappings:
/interface bridge vlan
add bridge=bridge untagged=bridge vlan-ids=1
add bridge=bridge tagged=bridge untagged=ether1 vlan-ids=111
add bridge=bridge tagged=bridge untagged=sfp-sfpplus1,sfp-sfpplus3,sfp-sfpplus5,sfp-sfpplus7 vlan-ids=172
add bridge=bridge tagged=bridge untagged=sfp-sfpplus2,sfp-sfpplus4,sfp-sfpplus6,sfp-sfpplus8 vlan-ids=173
Add interface for IP address assignment:
/interface vlan
add interface=bridge name=vlan111 vlan-id=111
add interface=bridge name=vlan172 vlan-id=172
add interface=bridge name=vlan173 vlan-id=173
All VLAN (1,111,172,173) get an address:
/ip address
add interface=bridge address=192.168.88.1/24 network=192.168.88.0
add interface=vlan111 address=172.16.11.13/27 network=172.16.11.0
add interface=vlan172 address=192.168.172.1/28 network=192.168.172.0
add interface=vlan173 address=192.168.173.1/28 network=192.168.173.0
VLAN configured; enable:
/interface bridge
set numbers=bridge vlan-filtering=yes
Based on my CRS309 iSCSI network.

Who is online

Users browsing this forum: cmmike and 50 guests